Public Sub NAddrAlign()
'Convert 1-Up Name and Address labels to Spread Sheet format.
'David McRitchie   -- to be included as:
'   http://www.mvps.org/dmcritchie/excel/code/naddralign.txt
'   2002-05-14 NaddrAlign macro work with single column in A
'   will accept 2 lines for name, single street addr,
'    blank row separates sets
Dim nCol As Long, nRow As Long, cRow As Long, lastrow As Long
Dim wsSource As Worksheet, wsNew As Worksheet
Dim lastcell As Range
nCol = 0
nRow = 1

Dim I As Long
Set lastcell = Cells.SpecialCells(xlLastCell)
lastrow = lastcell.Row + 1  'adjustment to help with insureCol
Set wsSource = ActiveSheet
Set wsNew = Worksheets.Add
Application.ScreenUpdating = False
Application.DisplayAlerts = False
For cRow = 1 To lastrow
   If Trim(wsSource.Cells(cRow, 1).Value) = "" Then
     If nCol <> 0 Then nRow = nRow + 1
     nCol = 0
   Else
     nCol = nCol + 1
     '--Street addresses normally begin with a number, know your data...
     If Left(wsSource.Cells(cRow, 1).Value, 1) < "A" Then
        If nCol < 3 Then nCol = 3
     End If
     wsNew.Cells(nRow, nCol).Value = wsSource.Cells(cRow, 1).Value
   End If
nextcrow:
Next cRow
Cells.EntireColumn.AutoFit
Application.ScreenUpdating = True     'place at end when debugged
Application.DisplayAlerts = True
End Sub