Option Explicit
Sub Bus_Sched()
'Bus Schedule  2001-04-17  in misc
'David McRitchie  http://www.mvps.org/dmcritchie/excel/excel.htm
' show times as  0:00 1:00 12:00 1:00  with PM in bold
' uses a second sheet to accomplish this  
'code for example in http://www.mvps.org/dmcritchie/excel/datetime.htm
Dim nCol As Long, nRow As Long
Dim cRow As Long
Dim lastrow As Double
Dim wsSource As Worksheet
Dim wsNew As Worksheet
Set wsSource = ActiveSheet
Dim iCell As String
Dim cell As Range
Dim oValue As Single
Sheets(ActiveSheet.Name).Copy After:=Sheets(ActiveSheet.Name)
Set wsNew = ActiveSheet
wsSource.Activate
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual 'xl95 uses xlManual
For Each cell In Cells.SpecialCells(xlCellTypeConstants, 1)
   oValue = cell.Value
   iCell = cell.Address(0, 0)
   If oValue < 1 Then   'test for time less than a day
     If oValue >= 12 / 24 Then
       wsNew.Range(iCell).Font.Bold = True
       If oValue >= 13 / 24 Then oValue = oValue - 0.5
       wsNew.Range(iCell) = "'" & _
         Trim(Left(Format(oValue, "h:mm    a/p"), 5))
       wsNew.Range(iCell).HorizontalAlignment = xlRight
    Else
       wsNew.Range(iCell).NumberFormat = "h:mm"
       wsNew.Range(iCell).HorizontalAlignment = xlRight
    End If
  End If
Next cell
Application.Calculation = xlCalculationAutomatic 'xl95 uses xlAutomatic
Application.ScreenUpdating = True
End Sub