ADDRESS "ISREDIT"; "MACRO (NEWNAME OLDNAME)"     /* REXX -- */
 /*  TITLE:      @RENAME THE MEMBER DISPLAYED IN EDIT TO NEWNAME     */
 /*  USERS:       TSO ISPF EDIT USERS             1986/08/28         */
 /*  CONTRIBUTED: J.FORD, SUPPLIED TO GLORIA CEVALLOS                */
 /*    MODIFIED 1992/06/01 TO PERMIT NEW OPTION -- NEWNAME OLDNAME   */
 /*    REXX     1994/06/01 J.Ford code converted to REXX by D.McRitchie*/
 /*                                                                  */
 /* RENAME    RENAMES MEMBER BEING EDITED TO INDICATED NAME          */
 /*           @RENAME NEWNAME                                        */
 /*           @RENAME NEWNAME OLDNAME                                */
 /*                                                                  */
 /* WITHIN ANOTHER CLIST THE TSO RENAME MAY WORK BETTER..            */
 /*    ... YOU MUST SAVE MEMBER BEFORE RENAMING.............         */
 /*    RENAME 'DATASET.NAME(OLDNAME)' 'DATASET.NAME(NEWNAME)'        */
IF OLDNAME = ""  THEN  "(OLDNAME) = MEMBER"
"(DSN) = DATASET"
"(FLAG) = DATA_CHANGED"
 NEWNAME = translate(NEWNAME)
 OLDNAME = translate(OLDNAME)
IF FLAG = "YES" THEN  DO
   SAY "'"DSN"("OLDNAME")' has been changed"
   SAY "YOU CAN ONLY RENAME SAVED DATA"
   SAY "DO YOU WANT THE MEMBER SAVED? ENTER Y OR N"
   PULL ANS;ans = translate(ans)
   IF ANS = "Y" THEN  DO
      "SAVE"
      SAY "'"DSN"("OLDNAME")' SAVED"
    END
END
IF NEWNAME = "" THEN  DO
     ZEDSMSG = "MISSING MEMBER"
     ZEDLMSG = "MEMBERNAME TO BE RENAMED WAS NOT SPECIFIED"
    Address "ISPEXEC" "SETMSG MSG(ISRZ000)"
    Exit 0
END
"(NNAME)  = DATAID"
Address "ISPEXEC" "LMOPEN DATAID(&NNAME) OPTION(INPUT) OPTION(OUTPUT) ORG(POCHK)"
 LMRC = RC
IF POCHK ^ = "PO" THEN signal CLOSEX
IF LMRC = 0 THEN  DO
    Address "ISPEXEC" "LMMREN DATAID(&NNAME) MEMBER(&OLDNAME) NEWNAME(&NEWNAME)"
    LRC = rc
    IF LRC = 0   THEN  DO
         ZEDSMSG = OLDNAME "renamed"
         ZEDLMSG = OLDNAME "renamed to" NEWNAME
        Address "ISPEXEC" "SETMSG MSG(ISRZ000)"
    END
    IF LRC = 4 THEN  DO
        ZEDSMSG =  NEWNAME "already exists"
        ZEDLMSG = NEWNAME "already exists, request NOT completed"
        Address "ISPEXEC" "SETMSG MSG(ISRZ000)"
    END
    IF LRC = 8 THEN  DO
        ZEDSMSG = OLDNAME "not found"
        ZEDLMSG = OLDNAME "not found, request NOT completed"
        Address "ISPEXEC" "SETMSG MSG(ISRZ000)"
    END
    IF lrc > 8 then do
        ZEDSMSG = "ERROR RC="LRC
         &ZEDLMSG = "ERROR RC="LRC NEWNAME "member NOT renamed"
        Address "ISPEXEC" "SETMSG MSG(ISRZ000)"
     END
 END
 CLOSEX: Address "ISPEXEC" "LMCLOSE DATAID(&NNAME)"
 Exit 0