ISREDIT MACRO (TO)
  ISREDIT (MEMBERX) = MEMBER
  ISREDIT (DSNX)    = DATASET
  IF &STR(&MEMBERX.) ^= &STR() THEN SET DSNX = &DSNX.(&MEMBERX.)
  ISREDIT (DCHG) = DATA_CHANGED
  IF &DCHG = YES THEN DO
     IF STR(&TO.) = &STR() THEN SET TO = NODE.USERID
     WRITE ******************************************************
     WRITE *          ===> @XMIT &TO.                    *
     WRITE *                                                    *
     WRITE * YOUR FILE HAS NOT BEEN SAVED AFTER MAKING CHANGES  *
     WRITE *                                                    *
     WRITE * YOUR FILE WILL NOT BE TRANSMITTED                  *
     WRITE *       ... SORRY BETTER LUCK NEXT TIME              *
     WRITE ******************************************************
     SET &ZEDSMSG = &STR(FAILED / NOT SAVED)
     SET &XEDLMSG = &STR(CHANGES DONE SINCE LAST SAVE -- +
                 REQUEST TO TRANSMIT NOT COMPLETED)
     SET &ZEDLMSG = &STR(&XEDLMSG.)
     ISPEXEC     SETMSG MSG(ISRZ000)
     EXIT CODE(4)
  END
  IF &STR(&TO.) = &STR() THEN DO
     IF &SYSUID. = IS03  THEN SET TO = CCC.BWDFM
     IF &SYSUID. = BWDFM THEN SET TO = AHCENTER.IS03
     IF &SYSUID. = IS0J  THEN SET TO = CCC.BWGWM
     IF &SYSUID. = BWGWM THEN SET TO = AHCENTER.IS0J
     IF &SYSUID. = C047  THEN SET TO = CCC.BWAGF
     IF &SYSUID. = CCAGF THEN SET TO = AHCENTER.C047
     IF &SYSUID. = IS0R  THEN SET TO = CCC.BWRFM
     IF &SYSUID. = BWRFM THEN SET TO = AHCENTER.IS0R
     WRITE TRANSMISSIONS BETWEEN DALLAS -- CCC, AND BBBBBBBBBBR -- CORPORAT
     WRITE WILL BE ENDING SOON ------ THIS IS A WARNING MESSAGE
     IF &STR(&TO.) = &STR() THEN DO
        WRITE PLEASE SUPPLY DESTINATION FOR TRANSMIT  OR CANCEL
        WRITE      E.G.  CCC.CCFML
        READ TO
        WRITE NEXT TIME USE ===> @XMIT &TO.
        ISREDIT LINE_BEFORE .ZF = NOTELINE "&SYSTIME. NEXT TIME USE +
          ===> @XMIT &TO."
     END
  END
  IF CANCEL = &STR(&TO.) THEN DO
     SET &ZEDSMSG = &STR(@XMIT CANCELLED)
     SET &ZEDLMSG = &STR(&ZEDSMSG. BY YOUR REQUEST)
     ISREDIT     LINE_BEFORE .ZF = NOTELINE "&SYSTIME. @XMIT    +
       &STR(--) CANCELLED"
     ISPEXEC     SETMSG MSG(ISRZ000)
     EXIT CODE(1)
  END
  TRANSMIT &TO DA('&DSNX.') SEQ
  SET I = &SYSINDEX(&STR( MSG),&NRSTR(&TO.))
  IF &EVAL(&I.) NE &EVAL(0) THEN DO
     /* ************************************************
     /* SUCCESS OR FAILURE WILL BE NOTED IN THE TRANSMIT
     /* IF MSG IS USED CONTINUING CLIST FROM THIS POINT
     /* MESSES UP SCREEN
     WRITE
     WRITE ********** THE USE OF "MSG" CAUSES A MINOR PROBLEM RETURNING TO ISPF EDIT PANEL
     WRITENR ********         HIT ENTER THEN HIT PA-2 TO FIX SCREEN
     READ XYZ
     EXIT CODE(0)
  END
  /* ************************************************
  SET RC = &LASTCC.
  IF &LASTCC = 0 THEN DO
  /*     SET &ZEDSMSG = &STR(RC=&RC.)
     SET &ZEDLMSG = TRANSMIT &STR(&TO.) DA('&DSNX.') SEQ &STR(--) +
       SUCCESSFUL
     ISREDIT     LINE_BEFORE .ZF = NOTELINE "&SYSTIME. +
                    TRANSMIT &STR(&TO.) DA('&DSNX.')"
     ISPEXEC     SETMSG MSG(ISRZ000)
     EXIT CODE(1)
  END
  ELSE DO
  /*     SET &ZEDSMSG = &STR(RC=&RC.)
     SET &ZEDLMSG = TRANSMIT &STR(&TO.) DA('&DSNX.')) SEQ &STR(--) +
       FAILED
     ISREDIT     LINE_BEFORE .ZF = NOTELINE "&SYSTIME. +
                    @XMIT  FAILED"
     ISPEXEC     SETMSG MSG(ISRZ000)
     EXIT CODE(1)
  END