00010011PROC 0 DEBUG SYMLIST TSO WHICH CPU UCB IPL HELP DS() VOLUME() UNIT() -
00011011   SYSTEM
00012011IF &SYSNEST = NO THEN CONTROL MAIN
00013011ELSE CONTROL NOFLUSH
00014011IF &DEBUG = DEBUG THEN CONTROL LIST CONLIST
00015011SET ERRTXT =
00016011ERROR GOTO ERROR
00017011PROFILE INTERCOM WTPMSG
00018011SET WHAT = &CPU.&UCB.&HELP.&IPL.&SYSTEM
00019011IF &WHAT = CPU THEN IVLCPU
00020011ELSE IF &WHAT = UCB THEN DO
00030011   CONTROL NOMSG
00040011   ERROR OFF
00050011   FREE FI(INFILE)
00060011   ERROR GOTO ERROR
00070011   CONTROL MSG
00080011   IF &DS.&VOLUME.&UNIT. = THEN DO
00090011      WRITENR ENTER DS('FULLY.QUALIFIED.DSN'), VOLUME(VOLSER), OR UNIT(XXX) ===>
00100011      READ
00110011      %WHICH UCB &SYSDVAL
00120011      EXIT CODE(&LASTCC)
00130011      END
00140011   IF &UNIT ^= THEN SET UNIT1 = UNIT(&UNIT)
00150011   ELSE IF &DS = OR &VOLUME ^= THEN SET UNIT1 = UNIT(SYSALLDA)
00160011   ELSE SET UNIT1 =
00170011   IF &DS = THEN SET DS1 = NEW DELETE BLOCK(80) SPA(0) RECFM(F) -
00180011      BLKSIZE(80)
00190011   ELSE SET DS1 = DS('&DS') SHR
00200011   IF &VOLUME ^= THEN SET VOLUME1 = VOLUME(&VOLUME)
00210011   ELSE SET VOLUME1 =
00220011   SET ERRTXT = FAILING COMMAND: ALLOCATE FI(INFILE) &DS1 &VOLUME1 &UNIT1
00230011   ALLOCATE FI(INFILE) &DS1 &VOLUME1 &UNIT1 TRACK
00240011   SET ERRTXT =
00250011   IVLUCB1
00260011   FREE FI(INFILE)
00270011   END
00280011ELSE IF &WHAT. = IPL THEN DO
00290011   WRITENR PRODUCTION 3090 IPL VOLUME:
00300011   ALLOCATE FI(INFILE) DS('SYS1.MVSPRD') SHR REUSE
00310011   IVLUCB1
00320011   $EDIT 'TECH.LIBR.CNTL(WHICHIPL)' MACRO(WHICHIPL)
00330011   IF &LASTCC ^= 0 THEN DO
00340011      WRITENR NOT ALL VOLUMES ARE AVAILABLE AT THIS TIME -- TERMINATING
00341011   END
00342011   WRITENR &RBL.      TEST 3090 IPL VOLUME:
00342111   ALLOCATE FI(INFILE) DS('SYS1.MVSTST') SHR REUSE
00342211   IF &LASTCC = 0 THEN DO
00342311         IVLUCB1
00342411         FREE FI(INFILE)
00342511      END
00342611   END
00342711ELSE IF &WHAT. = SYSTEM THEN DO
00342811   WRITE THIS IS NODE AHCENTER.
00342911   END
00343011ELSE GOTO SYNTAX
00344011EXIT CODE(0)
00345011ERROR: -
00346011   ERROR
00347011   WRITE THE COMMAND CONTAINS AN ERROR.  REVIEW THE SYNTAX, AND CORRECT THE COMMAND.
00348011   IF &ERRTXT ^= THEN WRITE &ERRTXT
00349011   SET ERRTXT =
00350011   WRITE
00360011   SET WHAT = &WHAT
00370011   IF &DS ^= THEN SET WHAT = &WHAT DS('&DS')
00380011   IF &VOLUME ^= THEN SET WHAT = &WHAT VOLUME(&VOLUME)
00390011   IF &UNIT ^= THEN SET WHAT = &WHAT UNIT(&UNIT)
00400011   SET WHAT = &SUBSTR(1:45,&WHAT                                             )
00410011   SET ENTER = CORRECT
00420011   GOTO SYNTAX2
00430011SYNTAX: -
00440011   CLRSCRN
00450011   WRITENR ***
00460011   READ
00470011   SET WHAT =
00480011   SET ENTER = ENTER
00490011SYNTAX2: -
00500011   WRITE SYNTAX:
00510011   WRITE    TSO WHICH CPU   . . . . . . . . . . . . . . . . WHICH CPU OR SYSTEM AM I RUNNING ON?
00520011   WRITE    TSO WHICH UCB DS('FULLY.QUALIFIED.DSN')   . . . WHAT IS THE UCB NUMBER AND VOLUME FOR THIS DATASET?
00530011   WRITE    TSO WHICH UCB VOLUME(VOLSER)  . . . . . . . . . WHAT IS THE UCB NUMBER FOR THIS VOLUME?
00540011   WRITE    TSO WHICH UCB UNIT(UNIT)  . . . . . . . . . . . WHAT IS A VOLUME NAME FOR THIS PUBLIC OR STORAGE UNIT?
00550011   WRITE              (NOTE: DS, VOLUME, AND UNIT PARAMETERS MAY BE COMBINED.)
00560011   WRITE    TSO WHICH IPL . . . . . . . . . . . . . . . . . WHICH IPL VOLUMES ARE CURRENTLY IN USE?
00570011   WRITE
00580011   EXIT CODE(&LASTCC)
00590011   END
00600011EXIT CODE(0)